Music and Railway

［選択処理］


図6-1.選択処理のイメージ
　前章で繰り返し処理について学びました。同じことを何回も繰り返し実行するというのはコンピュータの得意技です。繰り返し処理についてはまだまだお話したいことがあるのですが、このカテゴリーの目的のひとつに、短期間でプログラミング的思考を身につけるというのがあるので、繰り返し処理の続きは後の章で学ぶとして、ここはひとまず次の話題に進むことにします。

　昔話になりますが、管理人が小学校３年生のとき我が家に初めてカラーテレビが来ました。そのテレビは電源を入れた直後にマイコン制御で垂直同期が行われるようになっていたのですがテレピのボディに誇らし気に「人工頭脳付」というシールが貼ってありました。当時コンピュータは「人工頭脳」と呼ばれたものでした。今でも中国語では「電腦」（繁体）といいます。
　どうしてコンピュータが人間の脳に例えられるのかというと、コンピュータにはこれから学ぶ判断、処理の選択ができるという能力があるからです（もちろんそのようなプログラムが入っているからなのですが）。
　コンピュータが判断・処理の選択は、条件式が成立する(true)か成立しない(false)かで次の処理を実行するかどうかを決定する、というのが基本です(図6-1左)

。
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　

［偶数奇数判定プログラム］

　では。キーボードから入力された整数が偶数す奇数かを判定するプログラムを作ってみましょう。偶数とは２で割り切れる整数（0、2、4、6・・・）のことをいいます。対して奇数は２で割り切れない整数（1、3、5、7・・・）です。この判定を行なうには入力された数を２で割ってみて余りが出るかどうかをみればよいのですが、これをやるのにVB2022には便利な算術演算子がありましたね。そう、mod です。忘れてしまった方は第２章をもう一度見てください。
　プログラムの流れは図6-1右のようになります。

この流れにもとづいて作ったプログラムは次のようになります。

　1: Dim su As Integer
　2: Dim amari As Integer
　3: Console.Write(" 整数を入力してください ")
　4: su = Console.ReadLine()
　5: amari = su Mod 2
　6: If amari = 0 Then
　7:　　　 Console.WriteLine("偶数です")
　8: Else
　9:　　 　Console.WriteLine("奇数です")
10: End If
11: Console.ReadKey()

［プログラムの説明］

　１行目はキーボードから入力した整数を保存する変数、２行目は入力した整数を２で割った余りを代入する変数の宣言です。３行目は何を入力するかを表示し、４行目でキーボードから整数の入力を受けます。そして５行目は入力した整数を２で割った余りを求めるところです。
　次からが本章で中心になる判断・選択処理です。まず６行目です。If amari = 0 Thenとありますが、これは「もし、変数amariの値が0ならば次の処理を実行せよ」という意味です。どの処理を実行するのかというと７行目の「偶数です」と表示するところです。８行目の、Elseは「そうでなければ次の処理を実行せよ」という意味です。この場合なら９行目の「奇数です」と表示するところです。このようにIfとElseは条件が成立するかしないかで処理内容を分けるときに使いますが、どこまでが選択処理なのかということを示しているのが10行目のEnd Ifです。

［If 条件式 による処理の選択 ］
　If制御文の使い方をまとめておきます。最も基本的な使い方は
　　　If 条件式 Then
　　　　　条件が成立したときの処理（複数行でも可）
　　　End If
　これは条件が成立したときだけ特定の処理を行なう（条件が成立しないときは何もしない）場合です。

　　　If 条件式 Then
　　　　　条件が成立したときの処理（複数行でも可）
　　　Else
　　　　　条件が成立しなかったときの処理（複数行でも可）
　　　End If
　今のサンプルプログラムに出てきたもので、条件が成立するかしないかで処理内容を分ける場合です。

［条件式］
　選択処理や繰り返し処理の条件を指定する式を条件式といいます。条件式の書き方の基本を覚えましょう。
　条件式の書き方の基本的な形は
　　　式　比較演算子　式
です。条件式の場合、左辺は変数１個とは限りません。上のサンプルプログラムの６行目のamari = 0 は 0 = amari でもエラーにはなりません。あとはプログラムがわかりやすいかどうかです。そして条件式での ＝ は代入演算子ではなく等号です。ややこしいですが早いところ慣れてください。
　VB2022で使える比較演算子は次のとおりです。



図6-3.VB2022の比較演算子
［条件が複数あるとき～論理演算子］

図6-4.複数の条件式がある場合
　条件式は１つではなく２つ以上書くこともできます。図6-4左を見てください。今、２つの条件式ＡとＢがあるとします。条件式Ａが成立する範囲はＡとＣです。そして条件式Ｂが成立するのはＢとＣです。そうするとＣはＡ、Ｂ両方の条件式が成立する範囲ということになります。これを A And B と書きます。ＡかＢ、少なくともどちらか一方が成立する範囲はＡ、Ｂ、Ｃになります。これは A Or Bと書きます。Not は条件式が成立しない場合です。左の図で Not(A Or B) と書くと、Ｄの範囲になります。

この条件式と条件式を結ぶAnd、Or、Notのことを論理演算子といいます。VB2022で使える論理演算子はもっとあるのですが、この３つが基本になります。そして条件が成立することを真(True)、成立しないことを偽(False)といいます。

［Ifプロック］

　If～End IfまでのひとかたまりをIfブロックとよびます。Elseがある場合、Ifブロックの中はさらに２つのブロックに分かれます。それぞれのブロックは独立した部屋のようなものです。１つのブロックで１つのプログラムと考えてもけっこうです。これだけではさっぱりわからないと思いますので、実際のプログラムでみてみましょう。

［最小公倍数を求めるプログラム１］

　キーボードから入力した２つの整数ａとｂの最小公倍数を求めるプログラムを考えてみます。最小公倍数とは２つの整数の公倍数で共通するもののうちいちばん小さいものをいいます。ここでは小さい整数から順に２つの整数の公倍数かどうかを調べてゆくという方法をとります。整数ａ、ｂはせいぜい100くらいまで、調べる範囲は１～10000とします。プログラムの流れは下の図のようになります。



図6-5.最小公倍数を求めるプログラムの流れ

　この流れに基づいて作成したプログラムはこのようになります。

  1: Dim i As Integer
  2: Dim a As Integer
  3: Dim b As Integer
  4: Dim amari1 As Integer
  5: Dim amari2 As Integer
  6: Console.WriteLine("２つの数の最小公倍数を求める")
  7: Console.Write("１つめの数（整数） ") : a = Console.ReadLine()
  8: Console.Write("２つめの数（整数） ") : b = Console.ReadLine()
  9: For i = 1 To 10000
10:     amari1 = i Mod a
11:     If amari1 = 0 Then
12:        amari2 = i Mod b
13:        If amari2 = 0 Then
14:           Console.WriteLine()
15:           Console.WriteLine(i)
16:           Exit For
17:        End If
18:     End If
19: Next i
20: Console.ReadKey()

［プログラムの説明］

　今まで何回も出てきたところは省略し、要点だけに絞って説明します。
　９行目のForと19行目のNext iに囲まれた部分は整数１から10000までについて以下の処理（倍数かどうかを調べる）を繰り返しますという指示です。10行目は今調べている i の値 を整数ａで割った余りを求めています。ここで余りが０でなければこれはａの倍数ではありませんからａとｂの公倍数にはなり得ず以下の処理は不要となります。11行目のIfと18行目のEnd Ifに囲まれた中がIfプロックです。Ifブロックの中は独立した空間（この例の場合、ａの倍数だけが入れる部屋と考えてください）ですから、この中にさらにIfブロックを置くこともできます。12行目では i の値をｂで割った余りを求めます。
　ここで i はすでにａの倍数という条件はクリアしているのでさらにｂの倍数でもあるという条件もクリアできていればこの i の値はａとｂの公倍数ということになります。そして１から順番に調べていくうちに、最初にみつかった公倍数なのでこれが最小公倍数ということになります。このプログラムでは最小公倍数がみつかればあとの数について調べる必要はありません。16行目のExit Forは今入っているFor～Nextループから脱出せよ、という意味です。したがって最小公倍数がみつかれば20行目に移ってプログラム終了です。このようにForとIfを組み合わせて使うと、ある条件を満たしたら繰り返し処理終了という流れが作れます。

［最小公倍数を求めるプログラム２］

このプログラムは２つの整数の最小公倍数を求めるものなので、論理演算子Andを使って次のように書くこともできます。

  1: Dim i As Integer 
  2: Dim a As Integer
  3: Dim b As Integer
  4: Dim amari1 As Integer
  5: Dim amari2 As Integer
  6: Console.WriteLine("２つの数の最小公倍数を求める")
  7: Console.Write("１つめの数（整数） ") : a = Console.ReadLine()
  8: Console.Write("２つめの数（整数） ") : b = Console.ReadLine()
  9: For i = 1 To 10000
10:    amari1 = i Mod a
11:    amari2 = i Mod b
12:    If amari1 = 0 And amari2 = 0 Then
13:       Console.WriteLine()
14:       Console.WriteLine(i)
15:       Exit For
16:    End If
17: Next
18: Console.ReadKey()

　このプログラムでは10、11行目でａ、ｂで割った余りを求め、12行目でａ、ｂの公倍数かどうかをいっぺんで判定しています。論理演算子を使うとこのようにIfブロックの中にまたIfブロックということをしなくてプログラムの行数も少なくて済みます。どちらの形で書くかはプログラムへの要求によって異なってきます。

［演習３］三択クイズのプログラム
簡単な三択クイズを作ってみましょう。問題文の選択肢を表示し、答えを番号で入力、正解なら「正解です」と不正解なら「残念でした」と表示することにします（図6-6参照）。


図6-6.三択クイズのプログラム実行画面

［コラム］コンピュータは忠実過ぎる部下
　ここまでプログラミングをやってきた皆さんは、コンピュータは自分が作ったプログラムに従って忠実に動く部下のようにみえてきたことと思います。たしかにコンピュータは皆さんが指示したとおりの仕事を「疲れた～」とか「めんどくせ～」とか文句言わずにこなしてくれます。ただコンピュータは忠実過ぎて少々融通がきかないという面もあります。たとえば皆さんがプログラムを作って実行しようとしたところこのような画面になって実行できなかったということがあったりしませんでしたか。


図6-7.文法エラー

　プログラミング言語には「言語」というくらいですから文法があります。文法といっても主語とか述語というものではなく、プログラムの書き方のルールのことです。図6-7ではConsole.Writelineと書かなくてはならないところがdonsole.Writelineになっているので、コンピュータが？？？になってしまい実行できないのです。「こんなの１文字タイプミスしただけ。見りゃConsoleだってわかるだろが」と言いたいところですが、それをコンピュータに求めるのは無理なのです。このようなプログラムの書き方の間違いによるエラーを文法エラーといいます。


図6-8.実行時エラー

　プログラミング言語の文法どおりに書かれていればコンピュータはそれを忠実に実行しようとします。たとえ行く手に落とし穴があったとしてもです。図6-8のプログラムは文法どおりに書かれていますが、分母が０の割り算をやってしまっています。算数でも割る数が０の割り算は「不能」になりますが、コンピュータでも同じで扱えないデータが入ってきたり扱えない演算を実行しようとすると実行時エラーとなります。「計算できないとわかっているならその手前で止まれよ」と言いたくなりますが、これも無理です。そうしたいのならそのようにプログラムを組まなくてはなりません。


図6-9.論理エラー
　文法も間違いない、あり得ないデータも入ってこない、無理な演算もない、それでも発生するエラーがあります。それは論理エラーといい、プログラム中の命令や式にミスがあって正しい結果が得られない、というものです。論理エラーのやっかいなところは文法エラーや実行時エラーのようにエラーが発生したところでコンピュータが止まらないことです。なのでプログラムのミスをさがすのに大変苦労します。図6-9のプログラムは半径10の円の面積を求めるもののつもりなのですが、結果が間違っています（314.159になるはずです）。これは円の面積を計算するところで、S = pai * r ^ 2（またはS = pai * r * r）とすべきところをS = pai * r * 2としてしまっているためです（ちなみにこれだと円周の長さになってしまいます）。
　コンピュータによる計算、処理が正確だというのはプログラムやデータが正しく与えられている場合のことであり、これらが誤っていれば、間違った処理結果が出てしまったり途中で止まってしまったりします。

［昔はよかったなぁ］

　最小公倍数を求めるプログラム１を昔のBASICで書くと次のようになります。

図6-10.最小公倍数を求めるプログラムを昔のBASICで書くと
　昔のBASICではIfの後ろのEnd Ifというのがありませんでした。書かなくていいならラッキー！と思ってしまいそうですが、ちょっと待ってください。End IfがないということはIfブロックもないということです。条件が成立したときに行なう処理が複数行ある場合には、↑のプログラムの行番号60のようにthenの後ろに : で区切って複数の処理を書き連ねてゆくことになります。ここで条件が成立したときの処理が100行あったらどうなるでしょう。thenの後ろに : で区切られた処理が連なることになり大変見辛いプログラムになります。

　ここまでで、当カテゴリーで必要なVB2022の操作は習得できたと思います。本章以後はプログラム作成・修正画面、実行画面は省略します。VB2022の操作がまだ不安な方は、ここまでの章をもう一度復習してください。

　［順次処理と繰り返し処理］

　ここまででやってきたプログラムをもう一度見直してみましょう。コンピュータのプログラムはコンサートや運動会のプログラムと同じで、最初から終わりまで書かれている指示（命令）が順番に実行されてゆくものです。これを順次処理（順処理）といいます。順次処理はコンピュータのプログラミングの基本中の基本です。


図5-1.コンサートのプログラム

　図5-1はピアノリサイタルのプログラムの例です（しつこいようですが管理人の本業は・・・えーい、それもういいから）。音楽会では普通プログラムの順に曲が演奏されます。この例ならベートーヴェン、シューベルト、ドビュッシーの順に演奏されて終わります。よほどの事態が発生しない限りドビュッシーまで終わったところでベートーヴェンに戻ってもう一度全曲演奏されたり、シューベルトかドビュッシーのどちらか一方のみ演奏され他方は演奏されないということはありません。しかしコンピュータのプログラムでは、このようなことはしばしば行われます。同じ処理を繰り返し実行することを繰り返し処理、条件によりどちらか一方の処理のみ実行されることを選択処理といいます。この章では繰り返し処理について学びます。

　まずは簡単な平均を求めるプログラムで繰り返し処理の基本を身につけてください。
たとえば次のような５つの数の平均を求めるとします。
　　　67, 55, 42, 28, 30
　暗算が得意な方なら、これをパッと見て44.4とすぐにわかることでしょう。しかし記憶力も計算速度も人間よりはるかに勝っているはずのコンピュータにはそれができないのです。コンピュータで数の平均を求めるにはひとつひとつの数をエッチラオッチラと足し算していって、その合計をデータ件数で割る、という行程をたどる必要があります。この考え方に基づいたVB2022のプログラムはこうなります。

  1:Dim Gokei As Integer 
  2:Dim Ninzu As Integer
  3:Dim Tensu As Integer
  4:Dim i As Integer
  5:Dim Heikin As Single
  6:Gokei = 0
  7:Ninzu = 0
  8:For i = 0 To 4
  9:    Console.Write(" 点数 = ")
10:    Tensu = Console.ReadLine()
11:    Gokei = Gokei + Tensu
12:    Ninzu = Ninzu + 1
13:Next i
14:Heikin = Gokei / Ninzu
15:Console.WriteLine()
16:Console.WriteLine(" 平均 = " & Heikin)
17:Console.ReadKey()

以後、説明をスムーズに行なうためにプログラムリストに行番号を付けます。上のプログラムリストをコピー＆ペーストで
Sub Main～End Subに貼り付ける場合、面倒ですが、行番号は消してください。

［プログラムの説明］
１～５行目はプログラム中で使用する変数の宣言です。
　　　Gokei　　各々の生徒のテストの点数を加算する（整数型、テストの点は正の整数とします）
　　　Ninzu　　データの数（この場合、受験した生徒の人数）をカウントする（整数型）
　　　Tensu　　キーボードから入力したデータを受け付ける（整数型、テストの点は正の整数とします）
　　　i　　　　　　繰り返しの回数をカウントする（整数型）
　　　Heikin　　計算した平均点を代入する（実数型、割り算が入る以上、結果は少数になることもある）
　　　
　順番が入れ替わりますが、先に８行目の
　　　For i = 0 To 4
　について説明します。ここで ForはPresent for you💓のforではなく「～の間」の意味と考えてください。つまり
　　「変数i の値が０から（１ずつ増加して）４になるまで、以下の処理を繰り返せ」
　ということになります。これが繰り返し処理の指示です。どこまでを繰り返すのか、ということを示しているのが13行目のNext iです。
　これで９～12行目は、i=0 として１回目、i=1 として２回目・・・i=4 として５回目と５回繰り返されます。繰り返される処理内容はこうなります。
９行目：画面に「点数 = 」と表示します
10行目：キーボードから読み込んだデータを変数Tensuに格納します（変数Tensuにキーボードから入力されたデータを保存する、と考えてもＯＫです）
11行目：今、入力されたデータを変数Tensuに加算します
12行目：データの件数を＋１します
　この11～12行目は、数学の先生に叱られてしまいそうな式ですね。＝は数学では等号といい左辺と右辺の値が等しいという意味でした。VB2022に限らずプログラミング言語では＝は条件判定（後述）の場合を除き、統合ではなく代入演算子（右辺の値を左辺に代入する）です。忘れてしまった方は第３章をもう一度復習してください。
　繰り返しを抜けた後は平均の計算です。
14行目：データの合計÷データの件数を変数Heikinに代入（保存）します
15行目：結果を表示する前に１行空けます
16行目：計算結果（ここでは平均）を表示します
17行目：何かキーが押されるまで画面を閉じるのを待ちます

［コンピュータのプログラムならではの書き方］

　繰り返し処理の流れについてはご理解いただけたでしょうか。ではちょっと戻って先程説明を飛ばしてしまった６、７行目です。これらの変数GokeiとNinzuはキーボードからデータが入力される度に、そのデータを加算（足しこみ）し、データ件数をカウントするものですが、これを最初に０としています。そろばんで最初に「ご破算で願いましては」とやる（電卓なら最初にオールクリアキーを押す）のと同じです。どうしてこんなことをしなくてはならないかというと、変数は最初に宣言しただけではそこにどういうデータが入っているかわからない、からです。たとえば１行目でデータの合計をとるGokeiという整数型変数を宣言していますが、宣言した段階でここに100というデータが入ってしまっていて、かつ６行目がなかったらどうなるでしょうか。計算結果は全く誤ったものとなってしまいます（VB2022では数値型変数は宣言した段階で０が、ストリング型変数ではNull""が代入されるようになっているのですが、すべてのプログラミング言語がそうなっているとは限りません。管理人がコンピュータ屋だった頃使っていたCOBOLやFORTRAN言語ではそのような親切なことはやってくれませんでした）。合計をとるための変数は繰り返し処理に入る前に０にしておく、と覚えておきましょう。

［For ～ Nextによる繰り返しの条件］
　For ～ Nextで繰り返し処理の範囲を指定するには
　　　For 数値変数 = 初期値 To 終端値 Step 増分値
　　　Next 数値変数
　という書き方になります。ここで Nextの後の数値変数はForの後の数値変数と同じものにする必要があります。ただしNextの後の数値変数は省略することができます。省略した場合、そのNextはそこからさかのぼっていちばん近いForとペアとみなされます。
　For ～ Nextは「Forの後の数値変数が初期値から始まって増分値ずつ変化し、終端地を越えるまでの間、Nextの手前までの処理を繰り返せ」という指示になります。Step 増分値を省略するとStep 1とみなされます。つまり、次の３つのプログラムはどれも「VB2022」が５回表示されることになります。
　　　　Dim i As Integer
　　　　For i = 0 To 4
　　　　　　　Console.WriteLine("VB2022")
　　　　Next i
　　　　Console.ReadKey()

　　　　Dim i As Integer
　　　　For i = 3 To 7
　　　　　　　Console.WriteLine("VB2022")
　　　　Next i
　　　　Console.ReadKey()

　　　　Dim i As Integer
　　　　For i = 4 To 0 Step -1
　　　　　　　Console.WriteLine("VB2022")
　　　　Next i
　　　　Console.ReadKey()
　次のプログラムは初期値と終端値が同じです。この場合「VB2022」は１回だけ表示されます（For ～ Next内は１回だけ実行されます）。
　　　　Dim i As Integer
　　　　For i = 3 To 3
　　　　　　　Console.WriteLine("VB2022")
　　　　Next i
　　　　Console.ReadKey()

　次のように初期値が終端値を越えていると「VB2022」は１回も表示されません（For ～ Next内は１回も実行されません）。
　　　　Dim i As Integer
　　　　For i = 3 To 2
　　　　　　　Console.WriteLine("VB2022")
　　　　Next i
　　　　Console.ReadKey()
［注意］
１）Forの後の数値変数（繰り返しの回数を数えるのでループカウンタとよびます）は特に必要がない限り整数型にしておきましょう。次のプログラムは「VB2022」と10回表示されるかと思いきや実際には９回しか表示されません。この理由については後の章で詳しくお話します。
　　　　Dim i As Single
　　　　For i = 0.1 To 1 Step 0.1
　　　　　　　Console.WriteLine("VB2022")
　　　　Next i
　　　　Console.ReadKey()
２）ループカウンタは参照するのはかまいませんが値を変えるのは慣れないうちはやめておきましょう。具体的には式の右辺に使うのやConsole.Writeline()などで表示するのはかまいませんが、式の左辺に使うのやConsole.Readline()で値を代入するのは避ける方が無難です。
　次のプログラムを実行するとどうなるでしょう。
　　1:　　Dim i As Integer
　　2:　　For i = 11 To 20
　　3:　　　　　Console.WriteLine("ピーターパンは" & i & "歳になりました")
　　4:　　　　　i = 10
　　5:　　Next i
　　6:　　Console.ReadKey()

　実行するとこうなります。


　ループカウンタは11から始まって１ずつ増えて20を越えたら終わるはずです。３行目を見るとConsole.Writelineの(　)の中にループカウンタの i が入っているのでその時点でのループカウンタ i の値が表示されるので「ピーターパンは11歳になりました」「ピーターパンは12歳になりました」 ・・・と表示されてゆき「ピーターパンは20歳になりました」で止まるはずなのですが、実行すると「ピーターパンは11歳になりました」と延々と表示され終わりません。なんでこんなことになってしまうのでしょうか。そうです。４行目に i = 10 があるため（ここを通る度にループカウンタ i に10が代入されてしまうので)、Next iで繰り返しに戻っても i の値は常に11になってしまい終端値の20を超えることはないのです。「ピーターパンは永遠に歳とらない男の子だからこれでいいのだ」ではなく、プログラムのミスでコンピュータが止まらなくなっているのですからこれは立派な暴走です。

［演習２］粗利益の合計を求めるプログラム
　前章の［演習１］で作ったプログラムを改造し、照り扱い商品が５つある場合のそれぞれの粗利益と最後にすべての商品の粗利益合計を求めるプログラム（下図参照）を作りましょう。